CoDeSys. pointer to array

Вот что получилось с использованием OSCAT.Lib, а точнее не получилось

Функция crc16 по полиному 0x1021 в CoDeSys на ST:

-------------------------------
FUNCTION crc16_1021 : WORD

VAR_INPUT
pcBlock: POINTER TO BYTE;
len: WORD;
END_VAR

VAR
crc, i, w: WORD;
END_VAR
-------------------------------
crc := 16#FFFF;
WHILE (LEN > 0) DO
w := pcBlock^;
pcBlock := pcBlock + 1;
w := SHL(w,8);
crc := crc XOR w;
FOR i := 0 TO 7 DO
IF ((crc AND 16#8000) <> 0) THEN
crc := SHL(crc,1) XOR 16#1021;
ELSE
crc := SHL(crc,1);
END_IF
END_FOR
LEN := LEN - 1;
END_WHILE
crc16_1021 := crc;
RETURN;
-------------------------------

Тип INT в CoDeSys - 16-ти разрядный, потому что генерится для разных аппаратных платформ. Поэтому в настройках платформы проекта на закладке 'Общие' надо поставить галочку 'Байт-адресация всех типов'. Лучше всегда ставить эту галку так как это снимет многие другие проблемы.

Еще хочу сказать один важный вещь:
в протоколе MODBUS котрольная сумма считается совсем по другому! Особенно в очень популярных приборах ОВЕН, МВ110 и подобных. Там используется полином 0xA001 и сдвиг идет вправо.
Вот один из вариантов функции  crc16mbus  для контр.суммы в сетях MODBUS на C:

//------------------------------------------
unsigned short crc16mbus(char *buf, int Len)
{
int i, ib;
unsigned short crc = 0xFFFF;

for (ib=0; ib<Len; ib++)
{
crc ^= buf[ib];
for (i=0; i<8; i++)
{
if (crc & 0x0001) res = (res >> 1) ^ 0xA001;
else crc >>= 1;
}
}
return crc;
}
//------------------------------------------

А в CoDeSys на ST это будет так:

-------------------------------
FUNCTION crc16mbus : WORD

VAR_INPUT
pBuf: POINTER TO BYTE;
len: WORD;
END_VAR

VAR
crc, i, w: WORD;
END_VAR
-------------------------------
crc := 16#FFFF;
WHILE (LEN > 0) DO
w := pBuf^;
pBuf := pBuf + 1;
crc := crc XOR w;
FOR i := 0 TO 7 DO
IF ((crc AND 16#0001) <> 0) THEN
crc := SHR(crc,1) XOR 16#A001;
ELSE
crc := SHR(crc,1);
END_IF
END_FOR
LEN := LEN - 1;
END_WHILE
crc16mbus := crc;
-------------------------------

С уважением, SAN

Да и правда, сумму там считают как-то по своему по фирменному
Вот функция на ST:

-------------------------------
FUNCTION CalcFieldCRC : WORD

VAR_INPUT
pDataArray: POINTER TO WORD;
numberOfWords: WORD;
END_VAR

VAR
shifter, c, carry, CRC: WORD;
END_VAR
-------------------------------
CRC := 0;
WHILE (numberOfWords <> 0) DO
shifter := 16#8000;
c := pDataArray^;
pDataArray := pDataArray + 2;
REPEAT
carry := CRC AND 16#8000;
CRC := SHL(CRC,1);
IF ((c AND shifter) <> 0) THEN CRC := CRC + 1; END_IF
IF (carry <> 0) THEN CRC := CRC XOR 16#1021; END_IF
shifter := SHR(shifter,1);
UNTIL (shifter = 0)
END_REPEAT
numberOfWords := numberOfWords - 1;
END_WHILE
CalcFieldCRC := CRC;
-------------------------------

тут надо кое что сказать: судя по исходнику в этой функции элементы берутся не байтами а целыми словами (двойными батами), и значит указатель в буфере должен увеличиваться на 2. Так вот, в Си это происходит автоматически за счет указания типа WORD*. В CoDeSys такой номер не прокатит даже при указании типа POINTER TO WORD. Поэтому тут указатель передвигается на 2, сравнивал с работой оригинала - ответ вроде сходится.
Вобщем попробуйте

С уважением, SAN

Хотел спросить.
А получался ли у вас ответ 16#730C или 16#0C73
при подстановки массива (16#1А00 16#0000)?