Проблема с Stored

Поясните, если кто сталкивался с подобной проблемой!

Для сохранения настроек регулятора в область памяти под батарейкой и последующего востановления после перезагрузки контроллера ADAM5510 используется Stored.obj, написанный на С++. Переменные сохраняются и востанавливаются, но возникает проблема. если превысить количество сохраняемых переменных (примерно > 40 типа Float)(Хотя Stored.obj должен сохранять 1000 байт (250 пер. типа Float), то сразу после загрузки программы в контроллер, PLCNET OPC Server еще конфигурируется, но через некоторое время конфигурирование происходит с ошибками (имена сетевых переменных, их количество и т.д.). При этом, если успеть сконфигурировать PLCNET OPC Server, то в дальнейшем данные при работе OPC считываются без проблем.

Проблема оказывается не в Stored.obj, а в компиляторе UL16. Если ставишь 80x86 C/CPP-compatible compiler, то тут и начинаются "чудеса".

K10.map - 80x86 processors family compiler

 Start  Stop   Length Name               Class

 00000H 084DBH 084DCH SYSTEM             CODE
 084DCH 086D7H 001FCH CONST              DATA
 086D8H 09B74H 0149DH DATA               DATA
 09B75H 0A3D3H 0085FH VARLIST            DATA
 0A3D4H 0A3D4H 00000H STORED             DATA
 0A3E0H 0B3DFH 01000H STACK              STACK

Program entry point at 0000:73EF

K10.map - 80x86 C/CPP-compatible compiler

 Start  Stop   Length Name               Class

 00000H 04831H 04832H _TEXT              CODE
 04840H 04840H 00000H _FARDATA           FAR_DATA
 04840H 04840H 00000H _FARBSS            FAR_BSS
 04840H 04840H 00000H _OVERLAY_          OVRINFO
 04840H 04840H 00000H _1STUB_            STUBSEG
 04840H 05705H 00EC6H _DATA              DATA
 05706H 05709H 00004H DATA               DATA
 0570AH 05719H 00010H _CONST             DATA
 0571AH 057D7H 000BEH CONST              DATA
 057D8H 057D8H 00000H _CVTSEG            DATA
 057D8H 057D8H 00000H _SCNSEG            DATA
 057D8H 05A7BH 002A4H VARLIST            DATA
 05A7CH 05ABCH 00041H STORED             DATA
 05ABEH 05B75H 000B8H _CONST             CONST
 05B76H 05B7BH 00006H _INIT_             INITDATA
 05B7CH 05B7CH 00000H _INITEND_          INITDATA
 05B7CH 05B7CH 00000H _EXIT_             EXITDATA
 05B7CH 05B7CH 00000H _EXITEND_          EXITDATA
 05B7CH 05BBBH 00040H _BSS               BSS
 05BBCH 05BBCH 00000H _BSSEND            BSSEND
 05BC0H 06C3FH 01080H _STACK             STACK

Program entry point at 0000:0000 (а точка входа - NILL)

И размер у выходного ехе без срр на 2,5 килобайта меньше.

Переделываю программу на чистом asm. Посже опубликую результат.

;г=========================================================================ї
; і Объектный файл для UltraLogik 16
; і Сохраняемые переменные
; і (вариант 1)
; L=========================================================================

; Объединить несколько сегментов в группу,
; адресуемую с помощью одного сегментного регистра: Group
DGROUP  group VARLIST,DATA,STORED

; ===========================================================================
; Указание на сегмент: Externs
     extrn RESTORE_STATUS:far ; переменная - статус работы программы RESTORE
     extrn SAVE_STATUS:far    ; переменная - статус работы программы SAVE
     extrn STORED_VAR:far     ; переменная - контроль перекомпиляции проекта
 extrn STOREDMEM:far  ; Начало сегмента сохраняемых переменных
 extrn STOREDEND:far  ; Окончание сегмента сохраняемых переменных

; ===========================================================================
; Сегмент :code
SYSTEM  segment byte public 'CODE' use16
  assume ds:DGROUP, cs:SYSTEM
  
Seg_DGROUP    dw seg DGROUP
; Функция восстановления сохряняемых переменных
  public RESTOREMEM
RESTOREMEM proc near

 push    ax       ; сохранить предыдущий ax в стек
        push    es       ; сохранить предыдущий es в стек
        push    si       ; сохранить предыдущий si в стек
        push    ds       ; сохранить предыдущий ds в стек
        push    dx       ; сохранить предыдущий dx в стек
        push    bx       ; сохранить предыдущий bx в стек
       
     mov     ax, 3000h    ; в ах адресс начала области с питанием от батарейки
     mov     es, ax       ; в es адресс из ах "начало области с питанием от батарейки"
     mov     ds, word ptr cs:Seg_DGROUP ; устанавливаем ds:DGROUP
 mov ax, word ptr ds:STORED_VAR  ; получаем значение переменной STORED типа integer (глобальная) в которой
                                        ; "значение по умолчанию" сравнивается с данными по адресу 30000-30001
     xor     si, si       ; обнуление регистра si
     cmp  ax, word ptr es:[si]   ; сравниваем ax с (STORED из памяти под батарейкой)
 je  Metka_0             ; если равны, то переход на Metka_0
    ; иначе
 jmp Exit             ; безусловный переход: выход из подпрограммы

Metka_0:
 mov ax, offset STOREDEND  ; адресс конца блока (сегмента) сохраняемых перен. в регистр ax
 sub ax, offset STOREDMEM  ; вычитаем из ах адресс начала блока (сегмента)
                               ; сохраняемых перен. и получаем в ах количество
                               ; байт (размер) области сохраняемых перен.
 mov dx, ax       ; записываем в dx полученный в ах результат вычислений
 cmp dx, 3E8h     ; сравниваем dx с (1000)
 jle Metka_1      ; если dx меньше или равнен (1000), то переход на Metka_1
 mov dx, 3E8h     ; если dx больше (1000), то dx ограничиваем до (1000)

Metka_1:
 jmp Metka_3        ; безусловный переход:

Metka_2:
 mov al, byte ptr es:[si+2]   ; один байт в al, из области с питанием от батарейки
 mov bx, offset STOREDMEM  ; в bx - адресс начала блока (сегмента) сохраняемых перенных
 add bx, si      ; сложение bx и si, в bx следующий адресс блока (сегмента)
                 ; сохраняемых перенных, для записи бита из области STORED
 mov byte ptr ds:[bx], al  ; запись бита в ячейку блока (сегмента) сохраняемых перенных
 inc si          ; инкремент: увеличивает приемник (регистр) на 1
                 ; (перевод на следующий бит)

Metka_3:
 cmp si, dx      ; сравниваем si с dx
 jl Metka_2     ; если si меньше dx, то переход на метку Metka_2

Exit:
        mov    byte ptr ds:SAVE_STATUS, 0     ; останавливаем программу SAVE
        mov    byte ptr ds:RESTORE_STATUS, 0  ; останавливаем программу RESTORE
       
        pop    bx       ; восстановить bx основной программы
        pop    dx       ; восстановить dx основной программы
 pop    ds       ; восстановить ds основной программы
 pop    si       ; восстановить si основной программы
        pop    es       ; восстановить es основной программы
        pop    ax       ; восстановить ax основной программы
       
 call SAVEMEM    ; вызов программы сохранения в область под батарейкой

  retn         ; вернуться в основную программу
RESTOREMEM endp

; ---------------------------------------------------------------------------

  public SAVEMEM
SAVEMEM  proc near

 push    ax       ; сохранить предыдущий ax в стек
        push    ds       ; сохранить предыдущий ds в стек
 push    di       ; сохранить предыдущий di в стек
        push    es       ; сохранить предыдущий es в стек
        push    cx       ; сохранить предыдущий cx в стек
        push    bx       ; сохранить предыдущий bx в стек
  
     mov     ax, 3000h   ; в ах адресс начала области с питанием от батарейки
     mov     es, ax      ; в es адресс из ах "начало области с питанием от батарейки"  
     mov     ds, word ptr cs:Seg_DGROUP ; устанавливаем ds:DGROUP
 mov ax, word ptr ds:STORED_VAR  ; получаем значение переменной STORED типа integer (глобальная)
 xor     di, di      ; обнуление регистра di
 mov word ptr es:[di], ax  ; записываем в область под батарейкой значение STORED_VAR
 mov ax, offset STOREDEND   ; адресс конца блока (сегмента) сохраняемых перен. в регистр ax
 sub ax, offset STOREDMEM   ; вычитаем из ах адресс начала блока (сегмента)
                                ; сохраняемых перен. и получаем в ах количество
                                ; байт (размер) области сохраняемых перен.
 mov cx, ax         ; записываем в cx полученный в ах результат вычислений
 cmp cx, 3E8h       ; сравниваем cx с (1000)
  jle Metka_4       ; если cx меньше или равнен (1000), то переход на Metka_4
 mov cx, 3E8h      ; если cx больше (1000), то cx ограничиваем до (1000)

Metka_4:
 jmp Metka_6   ; безусловный переход:  short (короткий переход) если

Metka_5:
 mov bx, offset STOREDMEM ; в bx - адресс начала блока (сегмента) сохраняемых перенных
 add bx, di             ; получаем адресс бита в сегменте сохр. переменных
 mov dl, byte ptr ds:[bx]    ; значение бита из сегмента сохр. перем. в dl
 mov byte ptr es:[di+2], dl  ; в es+смещение (адрес в области с питанием от
                          ; батарейки) записываем бит из сегмента сохр. перем.
 inc di                 ; инкремент: увеличивает приемник (регистр) на 1
                         ; (перевод на следующий бит)

Metka_6:
 cmp di, cx     ; сравниваем di с cx для условного перехода jl
 jl Metka_5    ; если di меньше cx, то переход на Metka_5

 pop    bx       ; восстановить bx основной программы
 pop    cx       ; восстановить cx основной программы
 pop    es       ; восстановить es основной программы  
 pop    di       ; восстановить di основной программы
 pop    ds       ; восстановить ds основной программы
 pop    ax       ; восстановить ax основной программы

 retn           ; вернуться в основную программу
SAVEMEM  endp

SYSTEM  ends

; ===========================================================================
VARLIST  segment byte public 'DATA' use16
  assume ds:DGROUP
VARLIST  ends

; ===========================================================================
DATA  segment byte public 'DATA' use16
  assume ds:DGROUP
DATA  ends

; ===========================================================================
STORED  segment byte public 'DATA' use16
  assume ds:DGROUP
STORED  ends

  end

Я для управления програмой Restore при первом запуске использовал тумблер от NODE ID :

        mov dx,0138h ; Порт переключателей NODE ID
        in al,dx
        and al,80h      ; Верхний переключатель
        jz @Exit          ; Выход из программы Restore

Использование тумблера позволяет выбирать сохраняемые переменные берут значения по умолчанию или востанавливаются из энергонезависимой памяти

На счет неудобств согласен , но зато есть возможность перезапустить программу с установками по умолчанию в любой момент времени , что бывает иногда необходимо .